logo

한국어
:: ------------------------------------------------------------------
:: -
:: - 윈도우 사용자를 추가/삭제 한다.
:: -
:: ------------------------------------------------------------------

@ECHO OFF
SET USER_COMMENT="Test user group"

CALL :REMOVE_WINDOWS_USER TEST1
CALL :REMOVE_WINDOWS_USER TEST2
CALL :REMOVE_WINDOWS_USER TEST3

CALL :ADD_WINDOWS_USER TEST1 Passw0rd "테스트 사용자 1"
CALL :ADD_WINDOWS_USER TEST2 Passw0rd "테스트 사용자 2"
CALL :ADD_WINDOWS_USER TEST3 Passw0rd "테스트 사용자 3"

EXIT /B

:: ------------------------------------------------------------------
:: -
:: - FUNCTION: 윈도우 사용자를 추가한다.
:: - 인수: <윈도우계정> <비밀번호> <계정의풀네임>
:: -
:: ------------------------------------------------------------------
:ADD_WINDOWS_USER
NET USER %1 /ADD
NET USER %1 /FULLNAME:%3 /EXPIRES:NEVER /COMMENT:%USER_COMMENT% /LOGONPASSWORDCHG:NO /PASSWORDCHG:YES /PASSWORDREQ:YES /ACTIVE:YES
NET LOCALGROUP ADMINISTRATORS %1 /ADD
WMIC USERACCOUNT WHERE "NAME='%1'" SET PASSWORDEXPIRES=FALSE
NET USER %1 %2
ECHO "%1 added."
EXIT /B 0

:: ------------------------------------------------------------------
:: -
:: - FUNCTION: 윈도우 사용자를 삭제한다.
:: - 인수: <윈도우계정>
:: -
:: ------------------------------------------------------------------
:REMOVE_WINDOWS_USER
NET USER %1 /DELETE
IF EXIST "C:\Users\%1" RMDIR /S /Q "C:\Users\%1"
ECHO "%1 deleted."
EXIT /B 0